#Programa que transforma una frase a un título con todas las palabras en mayúsculas

	.include "servicios.asm"
	
	.eqv NEW_WORD 1
	.eqv NO_NEW_WORD 0
	.eqv A_MIN 0x61 #'a'
	.eqv Z_MIN 0x7A #'z'
	.eqv SPACE 0x20 #' '
	.eqv DIF -0x20 # a (0x61) - A(0x41)
	.eqv TITLE_SIZE 121
	
	.data
title:	.space TITLE_SIZE
msg1:	.string "Introduzca frase a capitalizar: "
msg2: 	.string "La frase transformada es: "
	
	.text
	#Imprimir mensaje para pedir frase
	li a7, PRINT_STRING
	la a0, msg1
	ecall
	
	#Leer la frase del usuario
	li a7, READ_STRING
	li a1, TITLE_SIZE
	la a0, title
	ecall

	#Imprimir salto de linea
	#li a7, PRINT_CHAR
	#li a0, '\n'
	#ecall

	#Transformación
	la t0, title
	li t1, NEW_WORD
	
bucle:	
	lb t2, 0(t0) #lee el siguiente caracter
	#comprueba si es el final de la cadena
	beqz t2, fin_transformacion
	
	#comprueba si es minúscula
	li t3, A_MIN	
	blt t2,t3, no_minuscula
	li t3, Z_MIN
	bgt t2, t3, no_minuscula
		#es minúscula
	li t4, NEW_WORD
	bne t1, t4, incrementa_puntero
		#es minúscula y tengo el flag que me indica que es nueva palabra => Tranformo
		
	addi t2, t2, DIF #transforma minúscula en mayúscula
	sb t2,0(t0)      #guarda en string
	li t1, NO_NEW_WORD # quita marca para no cambiar siguientes caracteres
	j incrementa_puntero

no_minuscula:
	li t1, NO_NEW_WORD #resetea el flag, solo se pone si hay un espacio
	#comprobar si es un espacio => para saber que siguiente vocal hay que transformarla.
	li t3, SPACE
	bne t2,t3,incrementa_puntero
	li t1, NEW_WORD
		
incrementa_puntero:	
	addi t0, t0, 1

	 j bucle	 

fin_transformacion:		
	#Imprimir mensaje para mostrar transformación
	li a7, PRINT_STRING
	la a0, msg2
	ecall

	#Imprimir frase transformada
	li a7, PRINT_STRING
	la a0, title
	ecall
	
	#Imprimir salto de linea
	li a7, PRINT_CHAR
	li a0, '\n'
	ecall
			
	#exit
	li a7, EXIT
	ecall