#  Programa: ejercicioP2.asm
# Propósito: Compara dos cadenas introducidas por el usuario (no diferencia mayúsculas de minúsculas)
#     Autor: Javier Macías del Campo
#     Fecha: 09/11/2025

	.include "servicios.asm"

	.eqv MAX_CADENA 101  #100 caracteres más fin cadena
	.eqv PASA_MAY -32    # Valor a sumar para pasar a mayúscula => ASCII('a')-ASCII('A')

	.data
cad1:	.space MAX_CADENA
cad2:	.space MAX_CADENA
txtC1:	.string "Introduzca la primera cadena: "
txtC2:	.string "Introduzca la segunda cadena: "
txtM1:	.string "La cadena primera es mayor"
txtM2:	 .string "La cadena segunda es mayor"
txtIg:	.string "Las dos cadenas son iguales"

	.text
	
	#mensaje solicitando primera cadena
	la a0, txtC1
	li a7, PRINT_STRING
	ecall
	
	#leemos la primera cadena
	la a0, cad1
	li a1, MAX_CADENA
	li a7, READ_STRING
	ecall

	#mensaje solicitando segunda cadena
	la a0, txtC2
	li a7, PRINT_STRING
	ecall
			
	#leemos la segunda cadena
	la a0, cad2
	li a1, MAX_CADENA
	li a7, READ_STRING
	ecall

	li s3, 'a'           #s3=>ASCII 'a'
	li s4, 'z'           #s4=>ASCII 'z'
	
	#comparamos las dos cadenas
	la s1, cad1           #s1=>puntero a cadena 1
	la s2, cad2           #s2=>puntero a cadena 2
bucle:	lb t1, 0(s1)          #t1=>caracter a analizar cadena 1 
	blt t1, s3, car2      #saltar a car2 si el caracter en t1 menor que 'a'
	bgt t1, s4, car2      #saltar a car2 si el caracter en t1 mayor que 'z'
	addi t1, t1, PASA_MAY #pasamos el caracter t1 a mayúscula

car2:	lb t2, 0(s2)          #t2=>caracter a analizar cadena 2
	blt t2, s3, comp      #saltar a comp(arar) si el caracter en t1 menor que 'a'
	bgt t2, s4, comp      #saltar a comp(arar) si el caracter en t1 mayor que 'z'
	addi t2, t2, PASA_MAY #pasamos el caracter t2 a mayúscula

comp:	bnez t1, sigue        #saltamos si no finalizada la cadena 1
	bnez t2, mayor2       #si no fin cadena 2, la cadena 2 es mayor
	la a0, txtIg          #hemos terminado también la cadena 2 => las cadenas son iguales; lo mostramos
	li a7, PRINT_STRING
	ecall
	j fin

sigue: 	blt t1, t2, mayor2   #cadena 2 mayor 
	bgt t1, t2, mayor1   #cadena 1 mayor
	addi s1, s1, 1       #si llega aquí, todavía son iguales, avanzamos punteros a las cadenas
	addi s2, s2, 1
	j bucle

mayor1:	la a0, txtM1        #mostramos que la cadena 1 es mayor
	li a7, PRINT_STRING
	ecall
	j fin			

mayor2:	la a0, txtM2        #mostramos que la cadena 2 es mayor
	li a7, PRINT_STRING
	ecall

fin:	li a7, 10           #terminamos
	ecall

#   Archivo: servicios.asm
# Propósito: Códigos servicios S.O. para incluir en los programas rars
#     Autor: ObiJuan (con adiciones y comentarios de Javier Macías del Campo)
#     Fecha: 09/11/2024

	.eqv PRINT_INT    1
	.eqv PRINT_INT_U  36
	.eqv READ_INT     5
	.eqv PRINT_STRING 4
	.eqv READ_STRING  8
	.eqv PRINT_CHAR   11
	.eqv READ_CHAR    12
	.eqv EXIT         10