Repository navigation
Examen: Parcial 1:2025_10_15:Datos
- Tiempo: 50 minutos
- Descripción: Examen Parcial 1. Laboratorio. Grado de Ciencia e Ingeniería de Datos
- Fecha: 2024/Octubre/9
- Temario: Sesiones L1, L2, L3 y L4
El examen se ha realizado a través de Aula virtual. Tiene dos partes: Test y un programa
- Realizado a través de Aula virtual
- 10 preguntas tipo test
- Las respuesats incorrectas restan un 33% del valor de la pregunta
- Solución disponible en Aula virtual
Enunciado
Escribir un programa en rars que, cíclicamente, vaya encenciendo los segmentos exteriores del display derecho y apagando los del izquierdo. Se mantendrá también una variable como contador del nº ciclo actual (no se destinará ningún registro de forma exclusiva para guardar la dirección de la variable ni su contenido).
La secuencia seguida sería por tanto:
Observaciones:
-
Nótese que el segmento a es 1, el b es 2, el c es 4 y así sucesivamente (se va doblando).
-
Si tuvieramos encendidos ya varios segmentos (por ejemplo, a y b, que significaría 1 + 2 = 3), para añadir el segmento c solo sería necesario sumar 4 (3 + 4 = 7). Para quitar un segmento, entonces restaríamos (ej.: 7 – 4 = 3; hemos apagado el segmento c).
-
Para hacer este ejercicio, se necesita utilizar un salto condicional. Se recomienda usar beq (branch if equal, esto es, saltar si son iguales), que apareció en dos ejercicios de L1. Se pone un ejemplo (si x1 = x2, se salta a la etiqueta seguir, en caso contrario, se continúa en la siguiente línea):
# Ejemplo: si x1 = x2, se salta a la etiqueta seguir
beq x1, x2, seguir
addi x3, x3, 1 # si no son iguales, se ejecuta esta instrucción
seguir:
# ...Notas:
-
El código que se entregue debe compilar. En caso contrario, el ejercicio se calificará con 0.
-
Tal y como se ha hecho en el Laboratorio, es recomendable que vaya haciendo alguna prueba mientras codifica en vez de hacer todo el ejercicio y luego probar.
-
Si ve que no le da tiempo a hacer todo el ejercicio, intente hacer al menos una parte del mismo (y que ésta funcione).
-
Un de los aspectos que se calificarán será la claridad del código. Es importante que se ajuste a lo indicado en el curso virtual, en Contenidos->Laboratorio->Comentarios y organización del código.
Como siempre ocurre al programar, existen infinitas soluciones. Pero en todas ellas se debe respetar la especificación
Este es el contenido del programa:
# Programa: cicloDisplay.asm
# Propósito: Cíclicamente, enciende los segmentos exteriores del display derecho y
# apaga los del izquierdo. Mantiene una variable contador del nº ciclo actual.
# Autor: Javier Macías del Campo
# Fecha: 04/10/2025
.eqv BASE_DISP 0xFFFF0010 #Direccion base de acceso a los displays
.eqv DISP_R 0 #Desplazamiento display derecho
.eqv DISP_L 1 #Desplazamiento display izquierdo
.eqv SEG_G 0x40 #Segmento g del display encendido (en binario: 0100 0000)
.eqv SEG_A_F 0x3F #Segmentos del a al f del display encendidos (en binario: 0011 1111)
.data
ciclo: .word 0 #variable indica el nº ciclo en el que se está
.text
li x1, BASE_DISP
li x4, SEG_G
inicio:
#actualizamos la variable del nº de ciclo
la x2, ciclo
lw x3, 0(x2)
addi x3, x3, 1
sw x3, 0(x2)
#inicializamos
li x2, 1 #contador del segmento, inicializado a 1 (segmento A)
li x3, 0 #acumulador segmentos encendidos display derecho (empezamos por todo apagado)
li x5, SEG_A_F #acumulador segmentos encendidos display izquierdo (empezamos por A a F encendidos)
cont:
sb x3, DISP_R(x1)
sb x5, DISP_L(x1)
beq x2, x4, inicio #si tocara el segmento G, hemos terminado un ciclo
add x3, x3, x2 #"encendemos" otro segmento más en el display derecho
sub x5, x5, x2 #"apagamos" otro segmento más en el display izquierdo
add x2, x2, x2 #siguiente segmento
j cont
#finalización programa (puesto por seguridad: no debería llegar aquí)
li a7, 10
ecall- Miguel Ángel de Miguel
- Javier Macías
